The Arsenal Files 2/The Arsenal Files 2 (Arsenal Computer).ISO/health/jaws231d.exe/INSTALL.DAT

Text File | 1994-06-06 | 48KB | 1,139 lines

/****************************************************************************
*   This file is protected by copyright (C) 1989-1994 by Henter-Joyce, Inc. *
*                          All rights reserved.                             *
*                                                                           *
*      Description: Installation script for use with Knowledge Dynamics'    *
*                   Install program.                                        *
*                                                                           *
*         Revision: 3.3                                                     *
*             Date: March 24, 1994                                          *
*           Author: Jeff Belina                                             *
*            State: Modifications for JAWS 2.3 Beta2 Installation           *
*            Notes: Added startup message "turn off smart screen"           *
*                   Made SET WP=/ND unconditional, Added SYNTH4 on          *
*                   "EXTRA SYNTH DISK", also add WP6.0 configs              *
*                   Added Support for 3.5" HD disks                         *
*                                                                           *
*         Revision: 3.4
*           Author: Jeff Belina                                             *
*            State: Modifications for JAWS 2.31 Installation                *
*            Notes: Changes for WP51 and WP60 installations and new files   *
*                                                                           *
*****************************************************************************/

@DefineProject
        @Name = "JAWS"
        @Version = "2.31"
        @Outdrive = C
        @Subdir = "\\"
        @InDiskBell = 1
        @Terse
@EndProject

/* Opening Screen */
@Display
        @Cls

@If (!@Exists "@InDrive:Register.exe")
                         Update and Demonstration
@EndIf
                         Installation Procedure for
                               Henter-Joyce's
                              JAWS version @Version
            JAWS is Copyright (C) 1989-1994 by Henter-Joyce, Inc.

        The installation process is virtually automatic with the
        exception of a few simple selections.  To interrupt and quit
        the installation process at any time press the Escape key,
        followed by the Enter key.  Otherwise press any key to continue.

        If you are using JAWS to install this update please turn off
        Smart Screens now.  To do this press INSERT+S and you should
        hear JAWS say Smart Screens OFF.

                                  @Pause

@EndDisplay

/* Check to see if running DOS 3.0 or higher */
@Display
        @Cls
        @If (@OSMajor < 3)
        JAWS version @Version REQUIRES PC or MS DOS Version 3.0 or
        higher to function properly.  Please obtain a new version of
        DOS, upgrade your computer system and then restart the JAWS
        installation procedure.  Press the Enter key to return to DOS.

                                  @Pause
        @Exit
        @EndIf
@EndDisplay

/* Desktop or Toshiba */
@GetOption
        @LocalWindow(16,39)
        @Cls

        JAWS needs to know the type of keyboard you are working with.

        If you are using a Toshiba laptop computer without a numeric
        pad select the "Toshiba" option.

        If you are using a Desktop keyboard with a numeric pad, or a
        Toshiba keyboard with a built-in or optional numeric keypad,
        select the "Desktop" option.

        Press the Enter key to select the "Desktop" option, or use the
        Down Arrow key to move the bar to the "Toshiba" option and then
        press the Enter key.

        @Option 300 = "Desktop"
        @Option 301 = "Toshiba"
@EndOption

@DefineVars
        @If (300 [= @Option)
                @Qstring @Computer = "Desktop"
        @ElseIf (301 [= @Option)
                @Qstring @Computer = "Toshiba"
        @EndIf
@EndVars

ChooseDrive:

/* Choose Drive */
@GetOutDrive
        @LocalWindow(14,39)
        @Cls
        On which disk drive do you wish to install JAWS?

        Press the Enter key to install to Drive C. Otherwise, Use the
        Up Arrow and Down Arrow keys to move the bar to the disk drive
        you wish to install to and then press the Enter key.

@EndOutDrive


/* Chose Directory */
@If (@Removable == 0)
     @DefineVars
                @Dir @JDir = "JAWS"
     @EndVars

     @GetSubdir @JDir
        @PROMPT = " Which directory? "
        @LocalWindow(15,40)
        @CLS

        Now you need to specify the destination directory where the
        JAWS system will be installed.

        We highly recommend you install JAWS to a directory named \JAWS.
@If (900 [! @Option)        This is what the installation program will default to. @Endif
        This will make things easier for all involved in the event you
        ever need technical support for JAWS from Henter-Joyce.

        Press the Enter key to name the directory @JDir, or edit the
        directory below using the arrow, delete, letter and number keys.
     @EndSubdir
@Else
        @DefineVars
                @Dir @JDir = ""
        @EndVars
@Endif


/* check for existing JAWS env. & voice files */
@If (@Exists "@OutDrive:\\@JDir\\*.JEF"||@Exists "@OutDrive:\\@JDir\\*.JVF")

        @Display
        @Cls
        We noticed that there is already a version of JAWS in the
        directory you have selected.  We recommend that you stop
        the installation now, back up the already existing files onto
        a floppy disk or copy them into another directory, delete
        them from the selected directory, and then run install again.
        You may exit install by pressing the Escape key and the Enter
        key at this time. You can run J_CVT23.EXE at any time to convert
        configuration files that have been backed up to the new JAWS
        format which began with JAWS 2.3.

        If you proceed with this installation we will convert the
        relevant files to a 2.3 format.  You may lose any configuration
        files (macros, frames, environment, voice, or dictionary) that
        you have created or modified, because the installation program
        will install new versions of some of these files.  That is why
        it is wise to have a back up.  Press any key to continue the
        installation, or press the Escape key and the Enter key to exit.
                                  @Pause
        @EndDisplay
@Spawn("j_cvt23 @OutDrive:\\@JDir /I")      /* /I stands for install       */
@Endif

ChooseSynth:
@FlushGroups

/* Chose Synthesizer */
@GetGroups
@LocalWindow(16,39)
        @CLS
        Which Synthesizer are you using?

        Use the Up Arrow and Down Arrow keys to move the bar to the
        synthesizer you wish to install and then press the Enter key.
        The list will scroll to reveal more synthesizers when you
        reach the bottom.

        @Set A = "Accent Mini or Toshiba"
        @Set B = "Accent P C"
        @Set C = "Accent S A"
        @Set M = "Aicom Messenger I C"
        @Set D = "Audapter"
        @Set E = "Braille 'N Speak 640 with indexing"
        @Set Y = "Braille 'N Speak & Braille Blazer without indexing"
        @Set F = "DECtalk & MultiVoice & Kurzweil Personal Reader"
        @Set G = "DECtalk P C"
        @Set H = "Double Talk Internal or External"
        @Set I = "Echo Internal Card"
        @Set J = "Echo External (New)"
        @Set Z = "Echo External (Old)"
        @Set L = "Lite Talk"
        @Set N = "Prose 4000"
        @Set P = "Sounding Board"
        @Set Q = "Synphonix (all models) & Votalker"
        @Set R = "Braille Mate"
        @Set S = "Xerox (Kurzweil) Reading Edge"
@If (@Exists "extra.dsk")
        @Set T = "External Apollo II (EXTRA DISK)"
//      @Set U = "Internal Apollo (Not Available yet)"
        @Set V = "External Infovox   (EXTRA DISK)"
        @Set W = "Internal Infovox   (EXTRA DISK)"
        @Set X = "SoundBlaster       (EXTRA DISK)"
@Endif
@EndGroups

/* Define variables for each synthesizers' name (JName) and
 * executable file (Exec) for use in messages to the user and in batch
 * file creation. */
@DefineVars
        @If ('A' [= @Group)
                @Qstring @Exec = "J_ACNTPC"
                @Qstring @JName = "Accent Mini"
                @Qstring @ExtraFiles = "SPKEMS.DVC"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('B' [= @Group)
                @Qstring @Exec = "J_ACNTPC"
                @Qstring @JName = "Accent P C"
                @Qstring @ExtraFiles = "SPKACNT.DVC"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('C' [= @Group)
                @Qstring @Exec = "J_ACNTSA"
                @Qstring @JName = "Accent S A"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('M' [= @Group)
                @Qstring @Exec = "J_ACNTPC"
                @Qstring @JName = "Messenger I C"
                @Qstring @ExtraFiles = "SPKMIC.DVC"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('D' [= @Group)
                @Qstring @Exec = "J_AUDAPT"
                @Qstring @JName = "Audapter"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('E' [= @Group || 'Y' [= @Group)
                @Qstring @Exec = "J_BNS"
                @Qstring @JName = "Braille 'N Speak"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('F' [= @Group)
                @Qstring @Exec = "J_DECTLK"
                @Qstring @JName = "DECtalk"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('G' [= @Group)
                @Qstring @Exec = "J_DECPC"
                @Qstring @JName = "DECtalk PC"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('H' [= @Group)
                @Qstring @Exec = "J_DOUBLE"
                @Qstring @JName = "Double Talk"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('I' [= @Group)
                @Qstring @Exec = "J_ECHO"
                @Qstring @JName = "Echo Internal Card"
                @Qstring @ExtraFiles = "ECHOPCII.COM and/or TALK.EXE"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('J' [= @Group)
                @Qstring @Exec = "J_ECHO"
                @Qstring @JName = "Echo External"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('Z' [= @Group)
                @Qstring @Exec = "J_ECHOXT"
                @Qstring @JName = "Echo External"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('L' [= @Group)
                @Qstring @Exec = "J_DOUBLE"
                @Qstring @JName = "LiteTalk"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('N' [= @Group)
                @Qstring @Exec = "J_PROSE"
                @Qstring @JName = "Prose 4000"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('P' [= @Group)
                @Qstring @Exec = "J_SB"
                @Qstring @JName = "Sounding Board"
                @Qstring @ExtraFiles = "SBLOAD.COM and SB.COM"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('Q' [= @Group)
                @Qstring @Exec = "J_SONIX"
                @Qstring @JName = "Symphonix or Votalker"
                @Qstring @ExtraFiles = "SONIXTTS.COM or both the files SONIX.COM and TTS.COM"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('R' [= @Group)
                @Qstring @Exec = "J_SB"
                @Qstring @JName = "Braille Mate"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('S' [= @Group)
                @Qstring @Exec = "J_KRE"
                @Qstring @JName = "K Reading Edge"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('T' [= @Group)
                @Qstring @Exec = "J_APOLXT"
                @Qstring @JName = "Apollo External"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('U' [= @Group)
                @Qstring @Exec = "J_APOLPC"
                @Qstring @JName = "Apollo Internal"
                @Qstring @ExtraFiles = "?"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('V' [= @Group)
                @Qstring @Exec = "J_VOXXT"
                @Qstring @JName = "Infovox External"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "Yes"
                @Qstring @NeedLpt = "No"
        @ElseIf ('W' [= @Group)
                @Qstring @Exec = "J_VOXPC"
                @Qstring @JName = "Infovox Internal"
                @Qstring @ExtraFiles = " "
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @ElseIf ('X' [= @Group)
                @Qstring @Exec = "J_SBLAST"
                @Qstring @JName = "Sound Blaster"
                @Qstring @ExtraFiles = "SBTALK.EXE"
                @Qstring @NeedCom = "No"
                @Qstring @NeedLpt = "No"
        @EndIf
@EndVars

@If ("Yes" == "@NeedLpt")
        @If (@LptTotal == 0)
        @Display
        @Cls
        The JAWS installation program could not locate a Parallel
        Printer port on your computer.  The synthesizer you've
        selected, the @JName, requires a parallel port to connect
        to your computer. If you selected this synthesizer in error,
        rerun the installation program and make a new choice.  If the
        @JName is the synthesizer you are trying to run, you will need
        to exit the installation program, check your hardware, and
        restart the installation process.
                                  @Pause
        @Exit
        @EndDisplay
        /* If only one LPT port, skip selection box */
        @ElseIf (@LptTotal == 1)
                @If (@Lpt (1))
                        @SetOption(61)
                @ElseIf (@Lpt (2))
                        @SetOption(62)
                @ElseIf (@Lpt (3))
                        @SetOption(63)
                @EndIf
        /* If more than one parallel port, bring up selection box for how
         * ever many there are, up to four */
        @ElseIf (@LptTotal > 1)
                @GetOption
                @LocalWindow(16,39)
                @Cls
        The Installation program has detected @LptTotal Parallel Printer ports.

        Which port do you wish to set up the @JName
        synthesizer to work with?

        Use the Up Arrow and Down Arrow keys to move the bar to the
        parallel port you wish to install to and then press the Enter key.

                @If (@Lpt(1))
                        @Option 61 = "LPT1"
                @EndIf
                @If (@Lpt(2))
                        @Option 62 = "LPT2"
                @EndIf
                @If (@Lpt(3))
                        @Option 63 = "LPT3"
                @EndIf
                @EndOption
        @EndIf

        @DefineVars
                @If (61 [= @Option)
                        @Qstring @LptPort = "LPT1"
                @ElseIf (62 [= @Option)
                        @Qstring @LptPort = "LPT2"
                @ElseIf (63 [= @Option)
                        @Qstring @LptPort = "LPT3"
                @EndIf
        @EndVars
@Else
        @DefineVars
                @Qstring @LptPort = " "
        @EndVars
@EndIf


/* Check for total number of serial ports and select one for use with
 * the Accent SA, the Braille N' Speak, the Audapter, the Echo XT, the
 * DECtalk, the Kurzweil, or the MultiVoice.
 */
@If ("Yes" == "@NeedCom")
        @If (@ComTotal == 0)
        @Display
        @Cls
        The JAWS installation program could not locate a serial port
        on your computer.  The synthesizer you've selected, the @JName,
        requires a serial port to connect to your computer. If you
        selected this synthesizer in error, rerun the installation
        program and make a new choice.  If the @JName is the synthesizer
        you are trying to run, you will need to exit the installation
        program, check your hardware, and restart the installation process.

                                  @Pause
        @Exit
        @EndDisplay
        /* If only one com port, skip selection box */
        @ElseIf (@ComTotal == 1)
                @If (@Com (1)) @SetOption(51)
                @ElseIf (@Com (2)) @SetOption(52)
                @ElseIf (@Com (3)) @SetOption(53)
                @ElseIf (@Com (4)) @SetOption(54)
                @EndIf
        /* If more than one comm port, bring up selection box for how
         * ever many there are, up to four */
        @ElseIf (@ComTotal > 1)
                @GetOption
                @LocalWindow(13,39)
                @Cls
        The Installation program has detected @ComTotal Serial ports.

        Which serial port do you wish to set up the @JName
        synthesizer to work with?

        Use the Up Arrow and Down Arrow keys to move the bar to the
        serial port you wish to install to and then press the Enter key.

                @If (@Com (1))
                        @Option 51 = "Com1"
                @EndIf
                @If (@Com (2))
                        @Option 52 = "Com2"
                @EndIf
                @If (@Com (3))
                        @Option 53 = "Com3"
                @EndIf
                @If (@Com (4))
                        @Option 54 = "Com4"
                @EndIf
                @EndOption
        @EndIf

        @DefineVars
                @If (51 [= @Option)
                        @Qstring @ComPort = "COM1"
                @ElseIf (52 [= @Option)
                        @Qstring @ComPort = "COM2"
                @ElseIf (53 [= @Option)
                        @Qstring @ComPort = "COM3"
                @ElseIf (54 [= @Option)
                        @Qstring @ComPort = "COM4"
                @EndIf
        @EndVars
@Else
        @DefineVars
                @Qstring @ComPort = " "
        @EndVars
@EndIf

@GetOption
        @LocalWindow(18,39)
        @SetOption(1)
        @SetOption(2)
        @SetOption(3)
        @SetOption(4)
        @SetOption(5)
        @SetOption(6)
        @SetOption(7)
        @SetOption(8)
        @CheckBox
        @Cls
        Do you wish to install the JAWS manual and any of the
        following companion files for JAWS to work in conjuction
        with Word Perfect, Lotus 1-2-3, Professional Write and
        other application programs?

        If you wish to install all the selections, simply press the
        Enter key.  If not, use the Up Arrow and Down Arrow keys to
        move the bar to the groups you do not wish to install and
        then press the Space Bar to toggle the option from "Yes" to
        "No".  The bar will advance to the next line automatically.
        Press the Enter key when you have finished selecting the
        options you want to install.

        @Option 1 = "The JAWS Manual"
        @Option 2 = "JAWS files for use with Word Perfect"
        @Option 3 = "JAWS files for use with Lotus 1-2-3"
        @Option 4 = "JAWS files for use with Professional Write"
        @Option 5 = "JAWS files for use with Procomm Plus"
        @Option 6 = "JAWS files for use with First Choice"
        @Option 7 = "JAWS files for use with FormMate"
        @Option 8 = "JAWS files for use with Arkenstone easy scan"
@EndOption

@If (2 [= @Option)
        @GetOption
        @LocalWindow(10,39)
        @CLS
        Which version of Word Perfect are you using?

        If you are using Word Perfect 6.0, simply press the Enter
        key.  Otherwise, use the Up Arrow and Down Arrow keys to
        move the bar to the Word Perfect version you use and then
        press the Enter key.

        @Option 10 = "Word Perfect Version 6.0"
        @Option 11 = "Word Perfect Version 5.1"
        @Option 12 = "Word Perfect Version 5.0"
        @Option 13 = "Word Perfect Version 4.2"
        @EndOption
@EndIf

@DefineVars
        @If (2 [= @Option)
          @If (10 [= @Option)
                @Qstring @WordPerfect = "Version 6.0"
          @ElseIf (11 [= @Option)
                @Qstring @WordPerfect = "Version 5.1"
          @ElseIf (12 [= @Option)
                @Qstring @WordPerfect = "Version 5.0"
          @Else
                @Qstring @WordPerfect = "Version 4.2"
          @EndIf
        @Else
                @Qstring @WordPerfect = "Not Installed"
        @EndIf
@EndVars

@Display
        @Cls
        You have chosen the following installation selections for JAWS:

        Keyboard Type: @Computer
        Disk: @OutDrive:
        @If (@Removable == 0)Directory: @JDir @EndIf
        Synthesizer: @JName
        JAWS Manual:@If (1 [= @Option) Yes @Else No @EndIf
        Word Perfect Support: @WordPerfect
        @If ("Yes" == "@NeedCom")Serial Port: @ComPort @ElseIf ("Yes" == "@NeedLpt")Parallel Printer Port: @LptPort @EndIf

        If all this is correct, please press any key to continue.
        Otherwise, press the Escape key followed by the Enter key to
        exit the installation and rerun the program to correct your
        selections.
                                  @Pause
@EndDisplay

/* If the register program exists on the first disk, and if there is
 * no preexisting JAWS.JNF file, run the register program  */
@If (@Exists "@InDrive:Register.exe")
        @If (!@Exists "@InDrive:JAWS.JNF")
                @Spawn("register")
        @EndIf
@EndIf

@GetOption
@LocalWindow(11,39)
@Cls
        We need to change the AUTOEXEC.BAT file.  If you are
        installing JAWS for the first time we recommend you let
        JAWS change this file for you.  To do this press the Enter
        key now.  If you already have JAWS running and you do not
        want to change this file, just skip this step by pressing
        the down arrow key then pressing the Enter key.
        @Option 377 = "Change AUTOEXEC.BAT (RECOMMENDED)"
        @Option 378 = "Skip this step for now"
@EndOption

@If (377 [= @Option)
     @SetAutoexec
     @OverWrite
     @Path = "@Outdrive:\\@JDir"
     @If (((@OSMajor * 100) + @OSMinor) >= 330)
           @Verbatim "rem Call the JAWS batch file to run JAWS"
           @Verbatim "CALL @OutDrive:\\@JDir\\JAWS.BAT"
     @Else
           @Verbatim "rem Run the JAWS batch file to load JAWS"
           @Verbatim "@OutDrive:\\@JDir\\JAWS.BAT"
     @EndIf
     @EndAutoexec
@Endif

/* check the config sys file if necessary */
@If ('A' [= @Group || 'B' [= @Group || 'M' [= @Group )
        @GetOption
        @LocalWindow(11,39)
        @Cls
        We need to change the CONFIG.SYS file.  If you are installing
        JAWS for the first time we recommend you let JAWS change this
        file for you.  To do this press the Enter key now.  If you
        already have JAWS running and you do not want to change this
        file, just skip this step by pressing the down arrow key then
        pressing the Enter key.
              @Option 477 = "Change CONFIG.SYS (RECOMMENDED)"
              @Option 478 = "Skip this step for now"
        @EndOption

        @If (477 [= @Option)
           @SetConfig
           @OverWrite
           @If ('A' [= @Group)
                 @Device = "@OutDrive:\\@JDir\\SPKEMS.DVC"
           @ElseIf ('B' [= @Group)
                 @Device = "@OutDrive:\\@JDir\\SPKACNT.DVC"
           @ElseIf ('M' [= @Group)
                 @Device = "@OutDrive:\\@JDir\\SPKMIC.DVC"
           @EndIf
           @EndConfig
        @EndIf
@EndIf

@Display
       @Cls
        The Install program is now ready to begin copying files to
        your system.  During this stage the computer will beep when
        it is through with a disk.  When this happens, remove your
        current disk from drive @InDrive, replace it with the next
        numbered disk, press the Enter key and let Install continue.
        If the system beeps again, put the next disk in and repeat
        the procedure.  Install will continue when it has the disk
        it needs.  When you have gone through all the disks in the
        set, return to the first disk.

        Press any key now to begin copying the JAWS files.

                                   @Pause
@EndDisplay


/* Install common files */

@DefineDisk
    @Label = "JAWS Disk 1"
    @If (@Exists "@InDrive:JAWS.JNF")
                @File       JAWS.JNF           @Out "JAWS @Version":@JDir\\*.*
    @EndIf

    @If (@Exists "@InDrive:Beta.RED")
                @BeginLib Beta.RED
                       @File     *.*           @Out "JAWS @Version":@JDir\\*.*
                @EndLib
    @EndIf

    @If (@Exists "@InDrive:MANUAL.RED")
        /* Get files from MANUAL.RED if asked for it */
        /* This technique only works on Disk 1! */
        @If (1 [= @Option)
                @BeginLib MANUAL.RED
                    @If (@Disksize @OutDrive < 720000)
                       @File  *.*      @Out "JAWS Manual":@JDir\\*.*
                    @Else
                       @File  *.*      @Out "JAWS @Version":@JDir\\Manual\*.*
                    @EndIf
                @EndLib
        @EndIf
    @EndIf

    /* End disk 1 if 360k, continue if 720k */
    @If (@Disksize @InDrive < 720000)
        @EndDisk                                 /* end disk 1, if 360K     */
        @DefineDisk
        @Label = "JAWS Disk 2"

        /* Get files from MANUAL.RED if asked for it */
//manual no longer on disk 2 of 5.25", now check on disk 5 6/94!
//        @If (1 [= @Option)
//                @BeginLib MANUAL.RED
//                    @If (@Disksize @OutDrive < 720000)
//                       @File  *.*      @Out "JAWS Manual":@JDir\\*.*
//                    @Else
//                       @File  *.*      @Out "JAWS @Version":@JDir\\Manual\*.*
//                    @EndIf
//                @EndLib
//        @EndIf
    @Endif

    /* COMMON2 has the rest of the common files, all .EXE's */
    @BeginLib COMMON2.RED
                @File          *.*      @Out "JAWS @Version":@JDir\\*.*
    @EndLib

    /* CMPANION.RED has the files for Application Configurations */
    @BeginLib CMPANION.RED
                /* Install Lotus 1-2-3 files if selected */
                @If (3 [= @Option)
                        @File       123.*      @Out "JAWS @Version":@JDir\\*.*
                 @EndIf
                /* Install Profession Write files if selected */
                @If (4 [= @Option)
                        @File       PW.*       @Out "JAWS @Version":@JDir\\*.*
                @EndIf

                /* Install Procomm Plus files if selected */
                @If (5 [= @Option)
                        @File       PCPLUS.*   @Out "JAWS @Version":@JDir\\*.*
                @EndIf

                /* Install First Choice files if selected */
                @If (6 [= @Option)
                        @File       FIRST*.*   @Out "JAWS @Version":@JDir\\*.*
                @EndIf

                /* Install FormMate files if selected */
                @If (7 [= @Option)
                        @File       FORMMATE.JMF  @Out "JAWS @Version":@JDir\\*.*
                @EndIf

                @If (8 [= @Option)
                        @File    SCANALL.JMF   @Out "JAWS @Version":@JDir\\*.*
                        @File    ARKSCAN.JMF   @Out "JAWS @Version":@JDir\\*.*
                        @File    CDP.JMF       @Out "JAWS @Version":@JDir\\*.*
                @EndIf

                /* Later may change this to be option 9, but for now just do regardless 6/94 */
                        @File    FULLTALK.JEF  @Out "JAWS @Version":@JDir\\*.*
                        @File    JAWSPCB.JMF   @Out "JAWS @Version":@JDir\\*.*

                @If (301 [= @Option)
                    @If (10 [= @Option)
                        @File    WP60.JFF      @Out "JAWS @Version":@JDir\\WP.JFF
                        @File    WP60.JMF      @Out "JAWS @Version":@JDir\\WP.JMF
                        @File    WP60.JDF      @Out "JAWS @Version":@JDir\\WP.JDF
                        /* Currently no specific configs for Toshiba's for WP 6.0 */
                        @File    WP.JFF        @Out "JAWS @Version":@JDir\\WP51.JFF
                        @File    WP.JEF        @Out "JAWS @Version":@JDir\\WP51.JEF
                        @File    WP51T.JMF     @Out "JAWS @Version":@JDir\\WP51.JMF
                    @Endif
                    /* Install Toshiba Word Perfect 5.1 files if selected */
                    @If (11 [= @Option)
                        @File    WP.JFF        @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF        @Out "JAWS @Version":@JDir\\*.*
                        @File    WP51T.JMF     @Out "JAWS @Version":@JDir\\WP.*
                        @File    WP60.JFF      @Out "JAWS @Version":@JDir\\WP60.JFF
                        @File    WP60.JMF      @Out "JAWS @Version":@JDir\\WP60.JMF
                        @File    WP60.JDF      @Out "JAWS @Version":@JDir\\WP60.JDF
                    @EndIf
                    /* Install Word Perfect 5.0 files if selected */
                    @If (12 [= @Option)
                        @File    WP.JFF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP50T.JMF    @Out @JDir\\WP.*
                    @EndIf
                    /* Install Word Perfect 4.2 files if selected */
                    @If (13 [= @Option)
                        @File    WP.JFF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP42T.JMF    @Out @JDir\\WP.*
                    @EndIf
                @Else
                    /* Install Word Perfect 6.0 files if selected */
                    @If (10 [= @Option)
                        @File    WP60.JFF      @Out "JAWS @Version":@JDir\\WP.JFF
                        @File    WP60.JMF      @Out "JAWS @Version":@JDir\\WP.JMF
                        @File    WP60.JDF      @Out "JAWS @Version":@JDir\\WP.JDF
                        @File    WP.JFF        @Out "JAWS @Version":@JDir\\WP51.JFF
                        @File    WP.JEF        @Out "JAWS @Version":@JDir\\WP51.JEF
                        @File    WP51.JMF      @Out "JAWS @Version":@JDir\\WP51.JMF
                    @Endif
                    /* Install Word Perfect 5.1 files if selected */
                    @If (11 [= @Option)
                        @File    WP.JFF        @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF        @Out "JAWS @Version":@JDir\\*.*
                        @File    WP51.JMF      @Out "JAWS @Version":@JDir\\WP.*
                        @File    WP60.JFF      @Out "JAWS @Version":@JDir\\WP60.JFF
                        @File    WP60.JMF      @Out "JAWS @Version":@JDir\\WP60.JMF
                        @File    WP60.JDF      @Out "JAWS @Version":@JDir\\WP60.JDF
                    @EndIf
                    /* Install Word Perfect 5.0 files if selected */
                    @If (12 [= @Option)
                        @File    WP.JFF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF       @Out "JAWS @Version":@JDir\\*.*
                        @File    WP50.JMF     @Out @JDir\\WP.*
                    @EndIf
                    /* Install Word Perfect 4.2 files if selected */
                    @If (13 [= @Option)
                        @File    WP.JFF      @Out "JAWS @Version":@JDir\\*.*
                        @File    WP.JEF      @Out "JAWS @Version":@JDir\\*.*
                        @File    WP42.JMF    @Out @JDir\\WP.*
                   @EndIf
                @EndIf
    @EndLib

@If (@Disksize @InDrive < 1440000)
/* Only one disk for High Density 3.5" */
/* End of disk 1 if 720k, End of disk 2 if 360k, no end if 3.5" HD */
@EndDisk

/* Now Define disk 2 for 720K or disk 3 and disk 4 for 360K */
@DefineDisk
    @If (@Disksize @InDrive < 720000)
        @Label = "JAWS Disk 3"
    @Else
        @Label = "JAWS Disk 2"
    @EndIf
@EndIf

    @If (@Exists "@InDrive:SYNTH1.RED")
        /* Get Files from SYNTH1 if it is on this disk */
        /* This is Disk 1 on 3.5" HD, Disk 2 on 3.5" DD, and Disk 3 on 5.25" DD */
        @BeginLib SYNTH1.RED
                @If ('P' [= @Group || 'R' [= @Group)
                        @File   J_SB.*          @Out "JAWS @Version":@JDir\\*.*
                /* Prose 4000 */
                @ElseIf ('N' [= @Group)
                        @File   J_PROSE.*       @Out "JAWS @Version":@JDir\\*.*
                @EndIf
        @EndLib
    @EndIf

    @BeginLib SYNTH2.RED
                /* Accent PC and Mini */
                @If ('A' [= @Group || 'B' [= @Group || 'M' [= @Group )
                        @File   J_ACNTPC.*      @Out "JAWS @Version":@JDir\\*.*
                        // ACNTPC bin file gotten from J_ACCENT.BIN
                        @File   J_ACCENT.BIN    @Out @JDir\\J_ACNTPC.BIN
                /* Accent SA */
                @ElseIf ('C' [= @Group)
                        @File   J_ACNTSA.*      @Out "JAWS @Version":@JDir\\*.*
                        // ACNTSA bin file gotten from J_ACCENT.BIN
                        @File   J_ACCENT.BIN    @Out @JDir\\J_ACNTSA.BIN
                /* Braille N' Speak */
                @ElseIf ('E' [= @Group || 'Y' [= @Group)
                        @File   J_BNS.*         @Out "JAWS @Version":@JDir\\*.*
                /* DECtalk, Kurzweil*/
                @ElseIf ('F' [= @Group)
                        @File   J_DECTLK.*      @Out "JAWS @Version":@JDir\\*.*
                @ElseIf ('N' [= @Group)
                        @File   J_PROSE.*       @Out "JAWS @Version":@JDir\\*.*
                @ElseIf ('G' [= @Group)
                        @File   J_DECPC.*       @Out "JAWS @Version":@JDir\\*.*
                @ElseIf ('S' [= @Group)
                        @File   J_KRE.*         @Out "JAWS @Version":@JDir\\*.*
                        /* Kurzweil reading edge bin file gotten from DECtalk */
                        @File   J_DECTLK.BIN    @Out "JAWS @Version":@JDir\\J_KRE.*
                @Endif
    @EndLib

    /* End this disk(disk 3) if 360k, continue if 720k */
    @If (@Disksize @InDrive < 720000)
        @EndDisk

        @DefineDisk
                @Label = "JAWS Disk 4"
    @EndIf

    @BeginLib Synth3.RED
                /* Double Talk or Lite Talk */
                @If ( 'H' [= @Group || 'L' [= @Group )
                        @File   J_DOUBLE.*     @Out "JAWS @Version":@JDir\\*.*
                /* Synphonix and Votalker */
                @ElseIf ('O' [= @Group || 'Q' [= @Group)
                        @File   J_SONIX.*      @Out "JAWS @Version":@JDir\\*.*
                /* Audapter */
                @ElseIf ('D' [= @Group)
                        @File   J_AUDAPT.*     @Out "JAWS @Version":@JDir\\*.*
                /* Echo PC internal or Echo PC external */
                @ElseIf ( 'I' [= @Group || 'J' [= @Group)
                        @File   J_ECHO.*       @Out "JAWS @Version":@JDir\\*.*
                @ElseIf ( 'Z' [= @Group)
                        @File   J_ECHO.BIN     @Out "JAWS @Version":@JDir\\J_ECHOXT.BIN
                        @File   J_ECHOXT.EXE   @Out "JAWS @Version":@JDir\\J_ECHOXT.EXE
                @EndIf
    @EndLib
@EndDisk
/* End of disk 2 if 720k, end of disk 4 if 360k */

@If (@Disksize @InDrive < 720000)
  @DefineDisk
      @Label = "JAWS Disk 5"
      @BeginLib SYNTH1.RED
          @If ('P' [= @Group || 'R' [= @Group)
             @File   J_SB.*          @Out"JAWS @Version":@JDir\\*.*
          /* Prose 4000 */
          @ElseIf ('N' [= @Group)
             @File   J_PROSE.*       @Out "JAWS @Version":@JDir\\*.*
          @EndIf
      @EndLib

      /* Get files from MANUAL.RED if asked for it */
      @If (1 [= @Option)
          @BeginLib MANUAL.RED
             @If (@Disksize @OutDrive < 720000)
                 @File  *.*      @Out "JAWS Manual":@JDir\\*.*
             @Else
                 @File  *.*      @Out "JAWS @Version":@JDir\\Manual\*.*
             @EndIf
          @EndLib
       @EndIf
  @EndDisk
@EndIf

@DefineDisk
    @Label = "EXTRA SYNTH DISK"
    @BeginLib SYNTH4.RED
        @If ('T' [= @Group )
           @File   J_APOL.BIN      @Out"JAWS @Version":@JDIR\\J_APOLXT.BIN
           @File   J_APOLXT.EXE    @Out"JAWS @Version":@JDIR\\J_APOLXT.EXE
        @ElseIf ('U' [= @Group )
           @File   J_APOL.BIN      @Out"JAWS @Version":@JDIR\\J_APOLPC.BIN
           @File   J_APOLPC.EXE    @Out"JAWS @Version":@JDIR\\J_APOLPC.EXE
        @ElseIf ('V' [= @Group )
           @File   J_VOX.BIN       @Out"JAWS @Version":@JDIR\\J_VOXXT.BIN
           @File   J_VOXXT.EXE     @Out"JAWS @Version":@JDIR\\J_VOXXT.EXE
        @ElseIf ('W' [= @Group )
           @File   J_VOX.BIN       @Out"JAWS @Version":@JDIR\\J_VOXPC.BIN
           @File   J_VOXPC.EXE     @Out"JAWS @Version":@JDIR\\J_VOXPC.EXE
        @ElseIf ('X' [= @Group)
           @File   J_SBLAST.*      @Out "JAWS @Version":@JDir\\*.*
        @EndIf
    @EndLib
@EndDisk

/* This forces INSTALL to beep and ask for the first disk
 * otherwise, it won't beep and ask for the first disk to
 * process the @Finish block commands
 */
@DefineDisk
        @Label = "JAWS Disk 1"

        @BeginLib COMMON1.RED
                @File          *.*      @Out "JAWS @Version":@JDir\\*.*
        @EndLib

        @If (301 [= @Option)
                @BeginLib TOSHIBA.RED
                        @File   *.*             @Out "JAWS @Version":@JDir\\*.*
                        @File   JAWSTOSH.JMF    @Out @JDir\\JAWS.*
                @EndLib
        @EndIf

@EndDisk

/* At this point, the actual copying will take place */
@Finish

/* Copy must be placed in Finish block */
@If (@Removable == 0)                       /* install on hard disk         */
    @Copy( "@InDrive:\\READ.ME", "@OutDrive:\\@JDir\\READ.ME")
    @Copy( "@InDrive:\\J_CVT23.EXE", "@OutDrive:\\@JDir\\J_CVT23.EXE")
    @Copy( "@InDrive:\\*.DOC",   "@OutDrive:\\@JDir\\*.DOC")
    @Copy( "@InDrive:\\*.TXT",   "@OutDrive:\\@JDir\\*.TXT")
@Endif
        /* Create Batch file for Jaws called JAWS.BAT */
        @Cls
        Creating JAWS batch file...
        @If (((@OSMajor * 100) + @OSMinor) < 330)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "wt", "Echo off\n")
        @Else
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "wt", "@@Echo off\n")
        @EndIf

        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "REM  Batch file for running JAWS version @Version\n")
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "REM  for the @JName Synthesizer\n")
//      @If (11 [= @Option)
//      Made /ND unconditional (3/94)
           @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "REM  The following SET command assures the compatibility\n")
           @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "REM  with Word Perfect 5.1 release March 9, 1992 or later\n")
           @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SET wp= %wp% /nd\n")
//      @Endif
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "@Outdrive:\n")
        @If ('R' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "MODE @ComPort 96 n 8 1 p\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "MODE lpt3 = @ComPort\n")
        @EndIf
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "CD \\@JDir\n")
        @If ('P' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SBLOAD\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SB /k0\n")
        @ElseIf ('I' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "If Exist ECHOPCII.com  ECHOPCII\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "TALK\n")
        @ElseIf ('O' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SONIX\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "TTS\n")
        @ElseIf ('L' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "MODE @ComPort 96,n,8,1\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "echo LiteTalk initialized > @ComPort\n")
        @ElseIf ('Q' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "If Exist SONIXTTS.COM Goto SONIXTTS\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SONIX\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "TTS\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "Goto NEXT\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", ":SONIXTTS\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SONIXTTS\n")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", ":NEXT\n")
        @ElseIf ('X' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "SBLAST.EXE\n"
        @EndIf
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "@Exec")
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " %1 %2 %3 %4 %5 %6 %7 %8 %9")
        @If ("Yes" == "@NeedCom")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /@ComPort")
        @EndIf
        @If ("Yes" == "@NeedLpt")
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /@LptPort")
        @EndIf
//made unconditional 6/94        @If (10 [= @Option)
            @Write("@Outdrive:\\@JDIR\\JAWS.BAT", "at", " /B8")
//      @EndIf
        @If (301 [! @Option)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /E")
        @EndIf
        @If (301 [= @Option)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /T")
        @EndIf
        @If ('Y' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /NI")
        @EndIf
        @If ('M' [= @Group)
            @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", " /Z\"|J\"")
        @EndIf
        @Write("@Outdrive:\\@JDir\\JAWS.BAT", "at", "\n")

        /* Check for JAWS Name File & JAWS Register File */
        @If (!@Exists "@OutDrive:\\@JDir\\JAWS.JNF")
        @Cls
        There is no JAWS name file, JAWS.JNF, in the @OutDrive:@JDir
        directory.  Therefore your JAWS will act as a demo version,
        after one thousand key strokes it will pause for five minutes,
        then give you another five hundred key strokes.  When you re-boot
        or re-load JAWS it will start over with one thousand keystrokes.
             @If (!@Exists "@InDrive:Register.exe")
        If you are updating a previous version of JAWS simply copy
        the JAWS.JNF file that you have been using into the @OutDrive:@JDir
        directory.  This will convert JAWS into a real version.  The
        JAWS.JNF file can be found among the files of your previous JAWS
        version, or on your original JAWS distribution disk.

        If you are installing a demonstration of JAWS, and not an update,
        the name file will not convert it to a live version of JAWS.
             @Else
        If you are installing JAWS for the first time you should run the
        register program to create the JAWS Name File, JAWS.JNF, and then
        copy it into the specified directory.  This will convert JAWS
        from a demo version to a real version.  To do this, wait until
        installation has ended, then type @InDrive: followed by enter, and
        then type REGISTER followed by enter.  Answer the questions and be
        prepared to put in the registration disk.  Then copy the JAWS.JNF
        file to the @OutDrive:@JDir directory.

        If you have installed JAWS and created the JAWS Name File before
        then you should get the JAWS.JNF file from the previous
        installation and copy it into the @OutDrive:@JDir directory.
             @EndIf
                                  @Pause
        @EndIf

        @If (" " != "@ExtraFiles")
        @Cls
        The synthesizer you have chosen, the @JName, comes with a
        diskette of utility programs.  After the installation process
        is over, you will need to copy the following file or files
        from that diskette into @OutDrive:@JDir.

           @If ('I' [= @Group)
              If you use EchoPCII echo card
                 Copy ECHOPCII.com and TALK.exe to @OutDrive:@JDir
              If you use EchoPC+ echo card
                 Copy TALK.exe to @OutDrive:@JDir
           @Else
              @ExtraFiles
           @EndIf

        Make certain that you have installed the software correctly
        for the @JName synthesizer before running JAWS.  If the
        appropriate software has already been installed you may ignore
        this message.

             @If ('Q' [= @Group)
        In the case of the Symphonix 215, you may need to order the
        file SONIXTTS.COM from Artic Technologies.

             @EndIf
                                  @Pause
        @EndIf

        @Cls
        @If (@Removable == 0)
        JAWS is now installed on your system.  To run JAWS, remove
        all diskettes from the floppy drives and reboot your computer.
        If JAWS does not run automatically, you must run it manually.
        To do this, you need to change to your @Outdrive:@JDir directory,
        and type J A W S then press the Enter key.
        @Else
        JAWS is now installed on your system.  To run JAWS, go to
        your @Outdrive: drive, type J A W S and press the ENTER key.
        @EndIf
        If you have any questions about running JAWS, please consult your
        JAWS training tapes and JAWS manual (available in print, on disk,
        and in braille), and your @JName manual.

        If it becomes necessary to call us for technical assistance please
        be at your computer with it turned on, and have a tape recorder
        handy to take notes.
                                  @Pause

        @Cls
        @ChDrive @OutDrive
        @ChDir "@JDir"
@EndFinish